// Malleable Matrix
// Robert Carlsen

/* Maps a capture object onto a grid of quads which are 
translated in z-space based on the position of the mouse.
Creates a fun distortion effect.
*/



import processing.video.*;
import processing.opengl.*;

boolean flip = false;
boolean saveFlag = false;

Capture video;

void setup() {
  size(640,480,OPENGL);
  frameRate(60);
  //smooth();
  
  video = new Capture(this,640,480,15);
  //println(video.list()); 
}

void draw() {
  background(102);

  lights();
  
  noStroke();
  int dia = 10;
  for(int i=0;i<height;i+=dia){
    for(int j=0;j<width;j+=dia){
      pushMatrix();
      translate(j,i);
      
      //calculate the z-pos of the corners
      float myDepth1 = dist(mouseX,mouseY,j,i);
      float myDepth2 = dist(mouseX,mouseY,j+dia,i);
      float myDepth3 = dist(mouseX,mouseY,j+dia,i+dia);
      float myDepth4 = dist(mouseX,mouseY,j,i+dia);
      
      
      if(flip){
        myDepth1=-myDepth1;
        myDepth2=-myDepth2;
        myDepth3=-myDepth3;
        myDepth4=-myDepth4;
      }
      
      
      beginShape();
      texture(video);
      vertex(0,0,myDepth1,j,i);
      vertex(dia,0,myDepth2,j+dia,i);
      vertex(dia,dia,myDepth3,j+dia,i+dia);
      vertex(0,dia,myDepth4,j,i+dia);
      endShape();
      popMatrix();
    }
  }

if(saveFlag) {
  //save the frame as an image sequence
    saveFrame();
}
}

void captureEvent(Capture video) {
  video.read();
}



void mousePressed() {
  if(mousePressed) {
    flip=!flip;
  }
}

void keyPressed() {
  if(key == 's'||key=='S') {
    saveFlag = !saveFlag;
  }
}